comment convertir un char en sa valeur code touche?

Réponse acceptée !
Salut,

Ord('A') 

et l'inverse  chr(65).

Réponse acceptée !
oh la oh la

c'est pas du tout comme ça que Keybd_Event fonctionne :


{Reste appuyé ou relache une touche aKey
en fonction du paramètre Down}
Procedure ToogleKey(Const aKey : Byte; Const Down: Boolean = True);
Var KeyDown : Byte;
Begin
  If  Not Down Then
    KeyDown := 2
  Else
    KeyDown := 0;
  keybd_event(aKey, 0, KeyDown, 0);
End;

{Reste appuyé ou relache les touches Ctrl et Alt
en fonction du paramètrte Down}
Procedure SimuleCtrlAlt(Const Down: Boolean = True);
Var KeyDown : Byte;
Begin
  ToogleKey(VK_MENU, Down);
  ToogleKey(VK_CONTROL, Down);
End;

{Appuie et relache une touche}
Procedure DoKeybdEvent(Const aKey : Byte);
Begin
  keybd_event(aKey , 0, 0, 0);
  keybd_event(aKey , 0, KEYEVENTF_KEYUP, 0);
End;

{Gère les touches à bascule VerrMaj VerrNum ArrêtDefil}
Procedure SimuleOnOfKey(Const aKey: Byte; Const IsOn: Boolean = True);
Begin
  If GetKeyState(aKey) <> Integer(IsOn) Then
    DoKeybdEvent(aKey);
End;

Procedure PressKey(Const aKey : Byte);
Begin
  ToogleKey(aKey);
End;

Procedure ReleaseKey(Const aKey : Byte);
Begin
  ToogleKey(aKey, False);
End;


{Gère l'appuie n'importe quelle touche du clavier
  c'est la procédure que l'on utilisera pour simuler l'appuie
  sur les différentes touches du clavier}
Procedure SimuleKey(Const aChar: Char);
Begin
  Case aChar Of
    {Touches majuscules}
    'A'..'Z','0'..'9','?','.','/','§','?','£','%','µ','°','+':
    Begin
      ToogleKey(VK_SHIFT);
      DoKeybdEvent(VkKeyScan(aChar));
      ToogleKey(VK_SHIFT, False);
    End;
    {Touches Ctrl+Alt}
    '~','#','{','[','|','`','\','^','@',']','}':
    Begin
      SimuleCtrlAlt;
      DoKeybdEvent(VkKeyScan(aChar));
      SimuleCtrlAlt(False);
    End;
    Else
    {Touches minuscules}
      DoKeybdEvent(VkKeyScan(aChar));
  End;
End;

pour l'utilisation c'est simple :
{On s'assure d'être en minuscule
   obligatoire pour le bon fonctionnement
   ne faire qu'une fois en début de code (dans le OnCreate par Ex.)}
  SimuleOnOfKey(VK_CAPITAL, False);
{et on simule l'appuie des touches}
For I := 1  To length(mot) Do
  SimuleKey(Mot[I]);

{pour les combinaisons de touche autres que "standard"}
{Exemple faire un Ctrl+C}
  PressKey(VK_CONTROL);
  SimuleKey('C');
  ReleaseKey(VK_CONTROL);
 
@+
Cirec

---

 
@+
Cirec

---